      complex function ccot (z)
c march 1979 edition.  w. fullerton, c3, los alamos scientific lab.
      complex z
      external alog, cabs, cos, cosh, exp, r1mach, sin, sinh,
     1  sqrt, tanh
      data eps, xmax, ylarge, ybig, rmin, ymin / 5*0.0, 1.5 /
c
      if (eps.ne.0.0) go to 10
      eps = r1mach(4)
      xmax = 1.0/eps
      ylarge = -0.5*alog(0.5*r1mach(3))
      ybig = -0.5*alog(0.5*sqrt(r1mach(3)))
      rmin = exp (amax1(alog(r1mach(1)), -alog(r1mach(2))) + 0.01)
c
 10   x = real (z)
      y = aimag (z)
      if (abs(y).gt.ylarge) go to 30
c
      x2 = 2.0*x
      y2 = 2.0*y
      if (abs(x2).gt.xmax) go to 20
      if (cabs(z).lt.rmin) call seteru (55hccot    cabs(z) is zero or so
     1 small that ccot overflows, 55, 5, 2)
c
      call entsrc (irold, 1)
      sn2x = sin(x2)
      call erroff
      den = cosh(y2) - cos(x2)
      call erroff
      call entsrc (irold2, irold)
c
      if (den.lt.x*x2*eps*eps) call seteru (74hccot    cot is nearly sin
     1gular, x is near a multiple of pi and y is near 0, 74, 3, 2)
      if (den.lt.x*x2*eps .and. abs(x).gt.0.5) call seteru (65hccot    a
     1nswer is lt half precision, x is near pi and y is near 0, 65, 1,1)
c
      ccot = cmplx (sn2x/den, -sinh(y2)/den)
      return
c
 20   if (abs(y).lt.ymin) call seteru (75hccot    answer would have no p
     1recision, abs(x) is very big and abs(y) small, 75, 4, 2)
      if (abs(y).lt.ybig) call seteru (69hccot    answer lt half precisi
     1on, abs(x) is very big and abs(y) small, 69, 2, 1)
c
      ccot = cmplx (0.0, 1.0/tanh(y2))
      return
c
 30   ccot = cmplx (0.0, sign (1.0, y))
      return
c
      end